Как узнать лицензионный ключ Windows. Код продукта

Иногда нужно переустанавливать даже достаточно надежные Windows 7, 8.1. Причины могут быть разные: стерлась или повреждена наклейка с кодом продукта, полный апгрейд компьютера, желание получить чистую систему с нуля, покупка более ёмкого HDD, или быстрого SSD. Скачать установочный образ лицензионной Windows 8.1 не составит труда, а вот отыскать коробочку с кодом продукта порой бывает очень сложно. Оставаться без компьютера, сейчас многим не приемлемо даже на несколько часов. И если вы еще не успели отформатировать диск C: , то у вас есть возможность узнать ключ Windows 8.1 или 7 установленной на вашем компьютере.

Для активации windows нам понадобиться 25-значный код (ключ) формата (XXXXX-XXXXX-XXXXX-XXXXX-XXXXX). Чтобы узнать какой ключ используется для активации вашей системы, можно воспользоваться VBS скриптом ниже.

Set WshShell = CreateObject("WScript.Shell")

regKey = "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\"

DigitalProductId = WshShell.RegRead(regKey & "DigitalProductId")

Win8ProductName = "Windows Product Name: " & WshShell.RegRead(regKey & "ProductName") & vbNewLine

Win8ProductID = "Windows Product ID: " & WshShell.RegRead(regKey & "ProductID") & vbNewLine

Win8ProductKey = ConvertToKey(DigitalProductId)

strProductKey ="Windows 8 Key: " & Win8ProductKey

Win8ProductID = Win8ProductName & Win8ProductID & strProductKey

MsgBox(Win8ProductKey)

MsgBox(Win8ProductID)

Function ConvertToKey(regKey)

    Const KeyOffset = 52

    isWin8 = (regKey(66) \ 6) And 1

    regKey(66) = (regKey(66) And &HF7) Or ((isWin8 And 2) * 4)

    j = 24

    Chars = "BCDFGHJKMPQRTVWXY2346789"

    Do

        Cur = 0

        y = 14

        Do

            Cur = Cur * 256

            Cur = regKey(y + KeyOffset) + Cur

            regKey(y + KeyOffset) = (Cur \ 24)

            Cur = Cur Mod 24

            y = y -1

        Loop While y >= 0

        j = j -1

        winKeyOutput = Mid(Chars, Cur + 1, 1) & winKeyOutput

        Last = Cur

    Loop While j >= 0

    If (isWin8 = 1) Then

        keypart1 = Mid(winKeyOutput, 2, Last)

        insert = "N"

        winKeyOutput = Replace(winKeyOutput, keypart1, keypart1 & insert, 2, 1, 0)

        If Last = 0 Then winKeyOutput = insert & winKeyOutput

    End If

    a = Mid(winKeyOutput, 1, 5)

    b = Mid(winKeyOutput, 6, 5)

    c = Mid(winKeyOutput, 11, 5)

    d = Mid(winKeyOutput, 16, 5)

    e = Mid(winKeyOutput, 21, 5)

    ConvertToKey = a & "-" & b & "-" & c & "-" & d & "-" & e

End Function

Теперь разберемся как этим скриптом можно воспользоваться.

Создаем текстовый файл. Открываем Блокнот, копируем код выше в него и сохраняем с любым именем. Конечно наш файл сохраниться с расширением .txt Например у нас получилось codprod.txt . Нам нужно дать понять системе, что это файл скрипта. Поэтому меняем расширение файла на .VBS у нас должно пучиться codprod.vbs.

codprod

Теперь мы можем запустить наш скрипт. В результате всплывет окошко на котором будет написан код продукта.

Если не хотите создавать скрипт самостоятельно, то можете скачать его с нашего сайта.